功能齐全的单片机音乐程序 单片机, 音乐, 程序, 功能

leslen

单片机最小系统，两位LED数码管由串口输出接两个164驱动，Lout,Rout为左右声道输出，
SET，  ALT0， ALT1为三个按键，也可自己在开始的I/O定义改成你想用的I/O口；12M晶振
若用89C51则只可装下约14首歌曲，用89C52则可装下近40曲

1. ; Electronic Music
   
2. ; Version 4.50
   
3. ; Copyright (c) XAJ 2001
   
4. ;============================
   
5. LOUT BIT P1.0 ;左声道输出
   
6. ROUT BIT P1.2 ;右声道输出
   
7. SET BIT P3.3 ;SET按键
   
8. ALT0 BIT P3.6 ;ALT0按键
   
9. ALT1 BIT P3.7 ;ALT1按键
   
10. 
    
11. ;REPNUM EQU 09H重复段编号
    
12. STATU EQU 0AH;状态寄存器
    
13. LDYDSR EQU 0BH;左低音度数
    
14. RDYDSR EQU 0CH;右低音度数
    
15. LDYAR EQU 0DH;左低音协助
    
16. RDYAR EQU 0EH;右低音协助
    
17. JPCLK EQU 0FH;节拍时钟
    
18. GENCLK EQU 10H;通用时钟
    
19. SNSDCLK EQU 11H;搜、存显示时钟
    
20. GEN16T0 EQU 12H;通用16位时钟
    
21. GEN16T1 EQU 13H;
    
22. SETST0 EQU 14H;设置状态
    
23. SETST1 EQU 15H; 定时时钟
    
24. DISNUM0 EQU 16H;显示数值
    
25. DISNUM1 EQU 17H;寄存器(2位)
    
26. CSN EQU 18H;当前曲曲号
    
27. REP0L EQU 19H;0号重复段地址
    
28. REP0H EQU 1AH;
    
29. REP1L EQU 1BH;1号重复段地址
    
30. REP1H EQU 1CH;
    
31. REP2L EQU 1DH;2号重复段地址
    
32. REP2H EQU 1EH
    
33. REP3L EQU 1FH;3号重复段地址
    
34. REP3H EQU 23H;
    
35. COSPEEDN EQU 24H;
    
36. SPENR EQU 25H;
    
37. 
    
38. LOCF BIT 00H;左声道开关标志
    
39. ROCF BIT 01H;右声道开关标志
    
40. SECHSTOF BIT 02H;搜索、存储标志
    
41. NEXTSF BIT 03H;下一曲标志
    
42. CSBESTOF BIT 04H;当前曲锁存/释放
    
43. CUYFD BIT 05H;当前音符显示
    
44. KSETF BIT 06H;SET键按下标志
    
45. KALT0F BIT 07H;ALT0键按下标志
    
46. KALT1F BIT 08H;ALT1键按下标志
    
47. SPEEDF BIT 09H;速度增/减标志
    
48. TONEF BIT 0AH;音调增/减标志
    
49. YPBIT BIT 0BH;音频逻辑输出
    
50. KBDISF BIT 0CH;键盘显示标志
    
51. REP0F BIT 0DH;0号重复段控制
    
52. REP1F BIT 0EH;1号重复段控制
    
53. REP2F BIT 0FH;2号重复段控制
    
54. REP3F BIT 10H;3号重复段控制
    
55. 
    
56. SBOTM EQU 25H;堆栈区(栈底)
    
57. BUFF0 EQU 43H;锁存曲数
    
58. BUFF EQU 44H;锁存曲缓冲区
    
59. ;============================
    
60. 
    
61. ;=========BEGIN==============
    
62. ORG 0000H
    
63. LJMP MAIN
    
64. ;---------T0INT--------------
    
65. ORG 000BH
    
66. LJMP T0INT
    
67. 
    
68. ;---------T1INT--------------
    
69. ORG 001BH
    
70. LJMP T1INT
    
71. ；1.音频发生器
    
72. ;---------YPFSQ(01)----------
    
73. ORG 0030H
    
74. T0INT: MOV TL0,R4
    
75. MOV TH0,R5
    
76. PUSH PSW
    
77. PUSH ACC
    
78. PUSH 01H
    
79. JB LOCF,ROPER
    
80. MOV R1,#00H
    
81. MOV A,LDYAR
    
82. T0LLOP: RRC A
    
83. MOV YPBIT,C
    
84. XCH A,R1
    
85. CJNE A,LDYDSR,T0LNEXT
    
86. MOV C,YPBIT
    
87. MOV LOUT,C
    
88. INC LDYAR
    
89. ; INC P0
    
90. SJMP ROPER
    
91. T0LNEXT: XCH A,R1
    
92. INC R1
    
93. SJMP T0LLOP
    
94. ROPER: JB ROCF,T0RETI
    
95. MOV R1,#00H
    
96. MOV A,RDYAR
    
97. T0RLOP: RRC A
    
98. MOV YPBIT,C
    
99. XCH A,R1
    
100. CJNE A,RDYDSR,T0RNEXT
     
101. MOV C,YPBIT
     
102. MOV ROUT,C
     
103. INC RDYAR
     
104. ; INC P2
     
105. SJMP T0RETI
     
106. T0RNEXT: XCH A,R1
     
107. INC R1
     
108. SJMP T0RLOP
     
109. T0RETI: POP 01H
     
110. POP ACC
     
111. POP PSW
     
112. RETI
     
113. ；2.通用时钟
     
114. ;---------CLOCK(02)----------
     
115. T1INT: MOV TL1,#0F0H
     
116. MOV TH1,#0D8H
     
117. PUSH PSW
     
118. PUSH ACC
     
119. INC JPCLK
     
120. INC GENCLK
     
121. INC SNSDCLK
     
122. MOV A,SNSDCLK
     
123. CJNE A,#0FFH,T1NEXT
     
124. CLR SECHSTOF
     
125. T1NEXT: INC GEN16T0
     
126. MOV A,GEN16T0
     
127. CJNE A,#100,T1NEXT0
     
128. MOV GEN16T0,#00H
     
129. INC GEN16T1
     
130. T1NEXT0: INC SETST0
     
131. MOV A,SETST0
     
132. CJNE A,#100,T1RETI
     
133. MOV SETST0,#00H
     
134. INC SETST1
     
135. MOV A,SETST1
     
136. CJNE A,#20,T1RETI
     
137. MOV SETST1,#00H
     
138. MOV STATU,#00H
     
139. T1RETI: POP ACC
     
140. POP PSW
     
141. RETI
     
142. ；3.显示子程序
     
143. ;---------DISPLAY(03)--------
     
144. DISPLAY: PUSH ACC
     
145. PUSH DPL
     
146. PUSH DPH
     
147. MOV DPTR,#T_FIGCODE
     
148. MOV A,DISNUM0
     
149. MOVC A,@A+DPTR
     
150. MOV SBUF,A
     
151. JNB TI,$
     
152. CLR TI
     
153. MOV A,DISNUM1
     
154. MOVC A,@A+DPTR
     
155. MOV SBUF,A
     
156. JNB TI,$
     
157. CLR TI
     
158. POP DPH
     
159. POP DPL
     
160. POP ACC
     
161. RET
     
162. T_FIGCODE:
     
163. DB 088H,0EBH,04CH,049H
     
164. ； 0 1 2 3
     
165. DB 02BH,019H,018H,0CBH
     
166. ; 4 5 6 7
     
167. DB 008H,009H,00AH,038H
     
168. ; 8 9 A B
     
169. DB 09CH,068H,01CH,01EH
     
170. ; C D E F
     
171. DB 080H,0E3H,044H,041H
     
172. ; 0. 1. 2. 3.
     
173. DB 023H,011H,010H,0C3H
     
174. ; 4. 5. 6. 7.
     
175. DB 000H,001H,002H,030H
     
176. ; 8. 9. A. B.
     
177. DB 094H,060H,014H,016H
     
178. ; C. D. E. F.
     
179. DB 0FFH,02FH,098H,07FH
     
180. ; 熄灭 # G -
     
181. DB 07CH,078H,0BCH,00AH
     
182. ; c o L R
     
183. DB 029H
     
184. ; Y
     
185. ；4.主程序MAIN
     
186. ;---------MAIN(04)-----------
     
187. MAIN: MOV R0,#01H
     
188. CLR A
     
189. CLRAM: MOV @R0,A
     
190. INC R0
     
191. CJNE R0,#80H,CLRAM
     
192. MOV R0,A
     
193. MOV SP,#SBOTM
     
194. MOV 08H,#BUFF
     
195. ;MOV 09H,#BUFF
     
196. MOV SCON,#00H
     
197. MOV TMOD,#11H
     
198. MOV TL1,#0F0H
     
199. MOV TH1,#0D8H
     
200. SETB EA
     
201. SETB ET0
     
202. SETB ET1
     
203. SETB TR1
     
204. 
     
205. START: MOV DPTR,#T_SONGS
     
206. RYF: LCALL RYFSUP
     
207. MOV A,R7
     
208. JZ START
     
209. CJNE R7,#0FFH,SYF
     
210. JBC NEXTSF,NEXTSCL
     
211. MOV A,STATU
     
212. JNZ GONSBQ
     
213. MOV A,BUFF0
     
214. JNZ MPSQCL
     
215. LCALL PAQSCL
     
216. SJMP MQNFD
     
217. MPSQCL: LCALL PSQSCL
     
218. MQNFD: LCALL QNFDSUP
     
219. MOVPJRYF: INC DPTR
     
220. INC DPTR
     
221. SJMP RYF
     
222. NEXTSCL: LCALL CSBESTOJG
     
223. JB CSBESTOF,CALLPSCL
     
224. LCALL PAQSCL
     
225. SJMP MOVPJRYF
     
226. CALLPSCL: LCALL PSQSCL
     
227. SJMP MOVPJRYF
     
228. GONSBQ: LCALL CSDPTR
     
229. INC DPTR
     
230. INC DPTR
     
231. SJMP MOVPJRYF
     
232. SYF: CJNE R6,#0FFH,CALLPLAY
     
233. LCALL REPCLSUP
     
234. SJMP MOVPJRYF
     
235. CALLPLAY: LCALL YFDSUP
     
236. LCALL PLAY
     
237. SJMP MOVPJRYF
     
238. ;5.读音符子程序
     
239. ;---------RYFSUP(05)--------
     
240. RYFSUP: CLR A
     
241. MOVC A,@A+DPTR
     
242. MOV R6,A
     
243. MOV A,#01H
     
244. MOVC A,@A+DPTR
     
245. MOV R7,A
     
246. RET
     
247. ；6.统唱曲首处理
     
248. ;---------PAQSCL(06)--------
     
249. PAQSCL: MOV CSN,R6
     
250. INC DPTR
     
251. INC DPTR
     
252. LCALL RYFSUP
     
253. MOV 02H,R6
     
254. MOV 03H,R7
     
255. RET
     
256. ;7.存唱曲首处理
     
257. ;---------PSQSCL(07)--------
     
258. PSQSCL: PUSH PSW
     
259. SETB RS0
     
260. CLR RS1
     
261. PSQC7E: CJNE R0,#7EH,PSQNEXT
     
262. PSQNEXT: JC PSQNEXT1
     
263. MOV R0,#BUFF
     
264. SJMP PSQC7E
     
265. PSQNEXT1: MOV A,@R0
     
266. JNZ PSQNEXT2
     
267. INC R0
     
268. INC R0
     
269. INC R0
     
270. SJMP PSQC7E
     
271. PSQNEXT2: MOV CSN,@R0
     
272. INC R0
     
273. MOV 02H,@R0
     
274. INC R0
     
275. MOV 03H,@R0
     
276. INC R0
     
277. POP PSW
     
278. LCALL CSDPTR
     
279. INC DPTR
     
280. INC DPTR
     
281. RET
     
282. ；8.曲号闪显子程序
     
283. ;---------QNFDSUP(08)-------
     
284. QNFDSUP: PUSH ACC
     
285. MOV GEN16T0,#00H
     
286. MOV GEN16T1,#00H
     
287. QNGON: LCALL CSNSDISN
     
288. LCALL DISPLAY
     
289. MOV GENCLK,#00H
     
290. QNWAIT: MOV A,GENCLK
     
291. CJNE A,#35,QNWAIT
     
292. MOV DISNUM0,#20H
     
293. MOV DISNUM1,#20H
     
294. LCALL DISPLAY
     
295. MOV GENCLK,#00H
     
296. QNWAIT1: MOV A,GENCLK
     
297. CJNE A,#15,QNWAIT1
     
298. MOV A,GEN16T1
     
299. CJNE A,#02,QNGON
     
300. POP ACC
     
301. RET
     
302. ；9.曲号送显示寄存器
     
303. ;---------CSNSDISN(09)------
     
304. CSNSDISN: MOV A,CSN
     
305. ANL A,#0FH
     
306. LCALL CSBESTOJG
     
307. JNB CSBESTOF,NADP
     
308. ADD A,#10H
     
309. NADP: MOV DISNUM0,A
     
310. MOV A,CSN
     
311. SWAP A
     
312. ANL A,#0FH
     
313. MOV DISNUM1,A
     
314. RET
     
315. ；10.当前曲是否被存储判断
     
316. ;---------CSBESTOJG(10)-----
     
317. CSBESTOJG:PUSH ACC
     
318. PUSH PSW
     
319. MOV A,BUFF0
     
320. JZ CLRCSTOF
     
321. MOV R0,#BUFF
     
322. CSBCMPCSN:MOV A,@R0
     
323. CJNE A,CSN,CSBGSCAN
     
324. SETB CSBESTOF
     
325. SJMP CSBRET
     
326. CSBGSCAN: INC R0
     
327. INC R0
     
328. INC R0
     
329. CJNE R0,#7EH,CSBNEXT
     
330. CSBNEXT: JC CSBCMPCSN
     
331. CLRCSTOF: CLR CSBESTOF
     
332. MOV R0,#BUFF
     
333. CSBCMP0: MOV A,@R0
     
334. JZ CSBRET
     
335. INC R0
     
336. INC R0
     
337. INC R0
     
338. CJNE R0,#7EH,CSBNEXT1
     
339. CSBNEXT1: JC CSBCMP0
     
340. CSBRET: POP PSW
     
341. POP ACC
     
342. RET
     
343. ；11.找当前曲首址
     
344. ;---------CSDPTR(11)--------
     
345. CSDPTR: MOV DPTR,#T_SONGS
     
346. CSDSCAN: LCALL RYFSUP
     
347. CJNE R7,#0FFH,CSDNEXT
     
348. MOV A,R6
     
349. CJNE A,CSN,CSDNEXT
     
350. SJMP CSDRET
     
351. CSDNEXT: INC DPTR
     
352. INC DPTR
     
353. SJMP CSDSCAN
     
354. CSDRET: RET
     
355. ；12.重复段处理子程序
     
356. ;---------REPCLSUP(12)------
     
357. REPCLSUP: MOV A,R7
     
358. ANL A,#0FH
     
359. CJNE A,#02H,CMPA3
     
360. MOV A,R7
     
361. SWAP A
     
362. ANL A,#0FH
     
363. JNZ H4CMP1
     
364. JNB REP0F,REPRET0
     
365. CLR REP0F
     
366. MOV DPL,REP0L
     
367. MOV DPH,REP0H
     
368. REPRET0: RET
     
369. H4CMP1: CJNE A,#01H,H4CMP2
     
370. JNB REP1F,REPRET
     
371. CLR REP1F
     
372. MOV DPL,REP1L
     
373. MOV DPH,REP1H
     
374. RET
     
375. H4CMP2: CJNE A,#02H,H4CMP3
     
376. JNB REP2F,REPRET
     
377. CLR REP2F
     
378. MOV DPL,REP2L
     
379. MOV DPH,REP2H
     
380. RET
     
381. H4CMP3: CJNE A,#03H,REPRET
     
382. JNB REP3F,REPRET
     
383. CLR REP3F
     
384. MOV DPL,REP3L
     
385. MOV DPH,REP3H
     
386. RET
     
387. CMPA3: CJNE A,#03H,REPRET
     
388. MOV A,R7
     
389. SWAP A
     
390. ANL A,#0FH
     
391. JNZ H4VS1
     
392. SETB REP0F
     
393. MOV REP0L,DPL
     
394. MOV REP0H,DPH
     
395. SJMP SREPHAD
     
396. H4VS1: CJNE A,#01H,H4VS2
     
397. SETB REP1F
     
398. MOV REP1L,DPL
     
399. MOV REP1H,DPH
     
400. SJMP SREPHAD
     
401. H4VS2: CJNE A,#02H,H4VS3
     
402. SETB REP2F
     
403. MOV REP2L,DPL
     
404. MOV REP2H,DPH
     
405. SJMP SREPHAD
     
406. H4VS3: CJNE A,#03H,REPRET
     
407. SETB REP3F
     
408. MOV REP3L,DPL
     
409. MOV REP3H,DPH
     
410. SREPHAD: MOV 09H,A
     
411. LCALL CSDPTR
     
412. REPGON: INC DPTR
     
413. INC DPTR
     
414. LCALL RYFSUP
     
415. CJNE R6,#0FFH,REPGON
     
416. MOV A,R7
     
417. SWAP A
     
418. ANL A,#0FH
     
419. CJNE A,09H,REPGON
     
420. REPRET: RET
     
421. ；13.音符显示子程序
     
422. ;---------YFDSUP(13)--------
     
423. YFDSUP: MOV A,STATU
     
424. JNZ YFDRET
     
425. JB SECHSTOF,YFDRET
     
426. JNB CUYFD,YFSLED
     
427. XZFCLD: MOV DISNUM0,#20H
     
428. MOV DISNUM1,#20H
     
429. SJMP YFDSPLAY
     
430. YFSLED: MOV A,R6
     
431. JZ XZFCLD
     
432. ANL A,#0FH
     
433. PUSH DPL
     
434. PUSH DPH
     
435. MOV DPTR,#T_YFDCOD
     
436. MOVC A,@A+DPTR
     
437. MOV DISNUM0,A
     
438. POP DPH
     
439. POP DPL
     
440. MOV A,R6
     
441. SWAP A
     
442. ANL A,#0FH
     
443. MOV DISNUM1,A
     
444. YFDSPLAY: LCALL DISPLAY
     
445. YFDRET: RET
     
446. T_YFDCOD: DB 20H ;--
     
447. DB 01H ; 1
     
448. DB 02H ; 2
     
449. DB 03H ; 3
     
450. DB 04H ; 4
     
451. DB 05H ; 5
     
452. DB 06H ; 6
     
453. DB 07H ; 7
     
454. DB 11H ;#1
     
455. DB 12H ;#2
     
456. DB 14H ;#4
     
457. DB 15H ;#5
     
458. DB 16H ;#6
     
459. ；14.唱音符子程序
     
460. ;---------PLAY(14)----------
     
461. PLAY: MOV A,R6
     
462. JZ PCOSPECL
     
463. PUSH DPL
     
464. PUSH DPH
     
465. MOV DPTR,#T_SD
     
466. ANL A,#0FH
     
467. MOVC A,@A+DPTR
     
468. XCH A,R6
     
469. SWAP A
     
470. ANL A,#0FH
     
471. MOV B,#12
     
472. MUL AB
     
473. ADD A,R6
     
474. ADD A,R2
     
475. RL A
     
476. MOV R6,A
     
477. MOV DPTR,#T_RAN
     
478. MOVC A,@A+DPTR
     
479. MOV TH0,A
     
480. MOV R5,A
     
481. MOV A,R6
     
482. INC A
     
483. MOVC A,@A+DPTR
     
484. MOV TL0,A
     
485. MOV R4,A
     
486. POP DPH
     
487. POP DPL
     
488. SETB TR0
     
489. PCOSPECL: LCALL COSPECL
     
490. PJPWAIT: MOV JPCLK,#00H
     
491. PDELAY: LCALL KCXCL
     
492. JB NEXTSF,PRET
     
493. MOV A,JPCLK
     
494. CJNE A,01H,PNEXT
     
495. PNEXT: JC PDELAY
     
496. DJNZ R7,PJPWAIT
     
497. PRET: CLR TR0
     
498. RET
     
499. ;---------TABSD-------------
     
500. T_SD: DB 01h ;useless
     
501. DB 01H
     
502. DB 03H
     
503. DB 05H
     
504. DB 06H
     
505. DB 08H
     
506. DB 0AH
     
507. DB 0CH
     
508. DB 02H
     
509. DB 04H
     
510. DB 07H
     
511. DB 09H
     
512. DB 0bH
     
513. ;---------TABRAN------------
     
514. T_RAN: DW 0F111H ;useless
     
515. dw 0f111h ; area 0
     
516. dw 0f1e8h
     
517. dw 0f2b2h
     
518. dw 0f373h
     
519. dw 0f426h
     
520. dw 0f4eeh
     
521. dw 0f571h
     
522. dw 0f609h
     
523. dw 0f699h
     
524. dw 0f71fh
     
525. dw 0f79fh
     
526. dw 0f817h
     
527. dw 0f889h ; area 1
     
528. dw 0f8f4h
     
529. dw 0f95ah
     
530. dw 0f9b9h
     
531. dw 0fa13h
     
532. dw 0fa68h
     
533. dw 0fab9h
     
534. dw 0fb04h
     
535. dw 0fb4ch
     
536. dw 0fb90h
     
537. dw 0fbcfh
     
538. dw 0fc0ch
     
539. dw 0fc45h ;area 2
     
540. dw 0fc7ah
     
541. dw 0fcadh
     
542. dw 0fcdch
     
543. dw 0fd0ah
     
544. dw 0fd34h
     
545. dw 0fd5ch
     
546. dw 0fd82h
     
547. dw 0fda6h
     
548. dw 0fdc8h
     
549. dw 0fde8h
     
550. dw 0fe06h
     
551. dw 0fe22h ; area 3
     
552. dw 0fe3dh
     
553. dw 0fe56h
     
554. dw 0fe6eh
     
555. dw 0fe85h
     
556. dw 0fe9ah
     
557. dw 0feaeh
     
558. dw 0fec1h
     
559. dw 0fed3h
     
560. dw 0fee3h
     
561. dw 0fef4h
     
562. dw 0ff02h
     
563. dw 0ff11h ;area 4
     
564. dw 0ff1fh
     
565. dw 0ff2bh
     
566. dw 0ff37h
     
567. dw 0ff42h
     
568. dw 0ff4dh
     
569. dw 0ff57h
     
570. dw 0ff60h
     
571. dw 0ff6ah
     
572. dw 0ff72h
     
573. dw 0ff7ah
     
574. dw 0ff81h
     
575. dw 0ff89h ; 5
     
576. ；15.共速处理
     
577. ;---------COSPECL(15)-------
     
578. COSPECL: MOV R1,03H
     
579. MOV A,COSPEEDN
     
580. JZ COSPRET
     
581. PUSH COSPEEDN
     
582. MOV A,R1
     
583. COSPEGON: MOV B,#08H
     
584. MUL AB
     
585. CLR C
     
586. SUBB A,R1
     
587. JNC COSPNEXT
     
588. DEC B
     
589. COSPNEXT: MOV R6,#03H
     
590. DIV8: CLR C
     
591. XCH A,B
     
592. RRC A
     
593. XCH A,B
     
594. RRC A
     
595. DJNZ R6,DIV8
     
596. MOV R1,A
     
597. DJNZ COSPEEDN,COSPEGON
     
598. POP COSPEEDN
     
599. MOV A,R1
     
600. JNZ COSPRET
     
601. MOV R1,#01H
     
602. COSPRET: RET
     
603. ；16.键盘查询处理
     
604. ;---------KCXCL(16)---------
     
605. KCXCL: LCALL KSET
     
606. LCALL KALT0
     
607. LCALL KALT1
     
608. JNB KSETF,KNEXT0
     
609. LCALL KSETCL
     
610. KSETSTC: MOV SETST0,#00H
     
611. MOV SETST1,#00H
     
612. SETB KBDISF
     
613. SJMP KDIS
     
614. KNEXT0: JNB KALT0F,KNEXT1
     
615. LCALL KALT0CL
     
616. SJMP KSETSTC
     
617. KNEXT1: JNB KALT1F,KDIS
     
618. LCALL KALT1CL
     
619. SJMP KSETSTC
     
620. KDIS: MOV A,STATU
     
621. JNZ KSSNSD
     
622. JNB SECHSTOF,KRET
     
623. KSSNSD: JNB KBDISF,KRET
     
624. CLR KBDISF
     
625. LCALL DISPLAY
     
626. KRET: RET
     
627. ；17.KSET键是否按下查询
     
628. ;---------KSET(17)----------
     
629. KSET: SETB SET
     
630. JB SET,CSETRET
     
631. MOV GENCLK,#00H
     
632. SETLOP: MOV A,GENCLK
     
633. CJNE A,#02,SETLOP
     
634. SETB SET
     
635. JB SET,CSETRET
     
636. CLR TR0
     
637. SETWAIT: SETB SET
     
638. JNB SET,SETWAIT
     
639. MOV GENCLK,#00H
     
640. SETLOP1: MOV A,GENCLK
     
641. CJNE A,#02,SETLOP1
     
642. SETB TR0
     
643. SETB KSETF
     
644. RET
     
645. CSETRET: CLR KSETF
     
646. RET
     
647. ；18.KALT0键是否按下查询
     
648. ;---------KALT0(18)---------
     
649. KALT0: SETB ALT0
     
650. JB ALT0,CALT0RET
     
651. MOV GENCLK,#00H
     
652. ALT0LOP: MOV A,GENCLK
     
653. CJNE A,#02,ALT0LOP
     
654. SETB ALT0
     
655. JB ALT0,CALT0RET
     
656. CLR TR0
     
657. ALT0WAIT: SETB ALT0
     
658. JNB ALT0,ALT0WAIT
     
659. MOV GENCLK,#00H
     
660. ALT0LOP1: MOV A,GENCLK
     
661. CJNE A,#02,ALT0LOP1
     
662. SETB TR0
     
663. SETB KALT0F
     
664. RET
     
665. CALT0RET: CLR KALT0F
     
666. RET
     
667. ；19.KALT1键是否按下查询
     
668. ;---------KALT1(19)---------
     
669. KALT1: SETB ALT1
     
670. JB ALT1,CALT1RET
     
671. MOV GENCLK,#00H
     
672. ALT1LOP: MOV A,GENCLK
     
673. CJNE A,#02,ALT1LOP
     
674. SETB ALT1
     
675. JB ALT1,CALT1RET
     
676. CLR TR0
     
677. ALT1WAIT: SETB ALT1
     
678. JNB ALT1,ALT1WAIT
     
679. MOV GENCLK,#00H
     
680. ALT1LOP1: MOV A,GENCLK
     
681. CJNE A,#02,ALT1LOP1
     
682. SETB TR0
     
683. SETB KALT1F
     
684. RET
     
685. CALT1RET: CLR KALT1F
     
686. RET
     
687. ;20.SET键处理
     
688. ;---------KSETCL(20)--------
     
689. KSETCL: INC STATU
     
690. MOV A,STATU
     
691. CJNE A,#07H,STATUDIS
     
692. MOV STATU,#00H
     
693. STATUDIS: MOV DISNUM0,#23H
     
694. MOV DISNUM1,STATU
     
695. RET
     
696. ;21.KALT0键处理
     
697. ;---------KALT0CL(21)-------
     
698. KALT0CL: MOV A,STATU
     
699. JNZ CASEB1
     
700. KA0S0GO: INC DPTR
     
701. INC DPTR
     
702. LCALL RYFSUP
     
703. MOV A,R7
     
704. JNZ EQUFF
     
705. MOV DPTR,#T_SONGS
     
706. SJMP KA0NEXT
     
707. EQUFF: INC A
     
708. JNZ KA0S0GO
     
709. KA0NEXT: LCALL RYFSUP
     
710. MOV CSN,R6
     
711. LCALL CSNSDISN
     
712. MOV A,DPL
     
713. CLR C
     
714. SUBB A,#02H
     
715. JNC KA0NEXT1
     
716. DEC DPH
     
717. KA0NEXT1: MOV DPL,A
     
718. CLR REP0F
     
719. CLR REP1F
     
720. CLR REP2F
     
721. CLR REP3F
     
722. SETB NEXTSF
     
723. SETB SECHSTOF
     
724. RET
     
725. CASEB1: CJNE A,#01H,CASEB2
     
726. INC LDYDSR
     
727. MOV A,LDYDSR
     
728. CJNE A,#04H,LDYDSL4
     
729. MOV LDYDSR,#00H
     
730. LDYDSL4: MOV DISNUM0,LDYDSR
     
731. MOV DISNUM1,#26H
     
732. RET
     
733. 
     
734. HCOSPEEDN EQU 12H
     
735. CASEB2: CJNE A,#02H,CASEB3
     
736. MOV A,COSPEEDN
     
737. CJNE A,#HCOSPEEDN,KA0NEXT4
     
738. KA0NEXT4: JNC KA0NEXT5
     
739. INC COSPEEDN
     
740. KA0NEXT5: MOV SPENR,COSPEEDN
     
741. LCALL SPENSDISN
     
742. RET
     
743. CASEB3: CJNE A,#03H,CASEB4
     
744. CLR SPEEDF
     
745. LCALL SPEEDCL
     
746. RET
     
747. CASEB4: CJNE A,#04H,CASEB5
     
748. CLR TONEF
     
749. LCALL TONECL
     
750. RET
     
751. CASEB5: CJNE A,#05H,CASEB6
     
752. CPL LOCF
     
753. JNB LOCF,KA0NEXT2
     
754. MOV DISNUM0,#24H
     
755. SJMP KA0NEXT3
     
756. KA0NEXT2: MOV DISNUM0,#25H
     
757. KA0NEXT3: MOV DISNUM1,#26H
     
758. RET
     
759. CASEB6: CJNE A,#06H,KA0RET
     
760. CPL CUYFD
     
761. JNB CUYFD,KA0NEXT6
     
762. MOV DISNUM0,#24H
     
763. SJMP KA0NEXT7
     
764. KA0NEXT6: MOV DISNUM0,#25H
     
765. KA0NEXT7: MOV DISNUM1,#28H
     
766. KA0RET: RET
     
767. ；22.速度数送显示寄存器
     
768. ;---------SPENSDISN(22)----
     
769. SPENSDISN:MOV A,SPENR
     
770. ANL A,#0FH
     
771. MOV DISNUM0,A
     
772. MOV A,SPENR
     
773. SWAP A
     
774. ANL A,#0FH
     
775. MOV DISNUM1,A
     
776. RET
     
777. ；23.速度处理
     
778. ;---------SPEEDCL(23)------
     
779. HSPEED EQU 02H;
     
780. LSPEED EQU 50H;
     
781. SPEEDCL: JB SPEEDF,DNSPEED
     
782. CJNE R3,#HSPEED,SCLNEXT
     
783. SCLNEXT: JC SCLNEXT1
     
784. DEC R3
     
785. SJMP SCLNEXT1
     
786. DNSPEED:
     
787. CJNE R3,#LSPEED,SCLNEXT2
     
788. SCLNEXT2: JNC SCLNEXT1
     
789. INC R3
     
790. SCLNEXT1: LCALL CSBESTOJG
     
791. JNB CSBESTOF,SCLNEXT3
     
792. INC R0
     
793. INC R0
     
794. MOV @R0,03H
     
795. SCLNEXT3: LCALL COSPECL
     
796. MOV SPENR,R1
     
797. LCALL SPENSDISN
     
798. RET
     
799. ；24.音调处理
     
800. ;---------TONECL(24)---------
     
801. ;LTONE EQU 00 ;C
     
802. HTONE EQU 11 ;B
     
803. TONECL: JB TONEF,DNTONE
     
804. CJNE R2,#HTONE,TCLNEXT0
     
805. TCLNEXT0: JNC TCLNEXT
     
806. INC R2
     
807. SJMP TCLNEXT
     
808. DNTONE: MOV A,R2
     
809. JZ TCLNEXT
     
810. DEC R2
     
811. TCLNEXT: LCALL CSBESTOJG
     
812. JNB CSBESTOF,TCLNEXT1
     
813. INC R0
     
814. MOV @R0,02H
     
815. TCLNEXT1: PUSH DPL
     
816. PUSH DPH
     
817. MOV DPTR,#T_TONDISC
     
818. MOV A,R2
     
819. RL A
     
820. MOVC A,@A+DPTR
     
821. MOV DISNUM1,A
     
822. MOV A,R2
     
823. RL A
     
824. INC A
     
825. MOVC A,@A+DPTR
     
826. MOV DISNUM0,A
     
827. POP DPH
     
828. POP DPL
     
829. RET
     
830. T_TONDISC:DW 200CH ; C
     
831. DW 210CH ;#C
     
832. DW 200DH ; D
     
833. DW 210DH ;#D
     
834. DW 200EH ; E
     
835. DW 200FH ; F
     
836. DW 210FH ;#F
     
837. DW 2022H ; G
     
838. DW 2122H ;#G
     
839. DW 200AH ; A
     
840. DW 210AH ;#A
     
841. DW 200BH ; B
     
842. ;25.KALT1键处理
     
843. ;---------KALT1CL(25)--------
     
844. KALT1CL: MOV A,STATU
     
845. JNZ CASE1
     
846. LCALL CSBESTOJG
     
847. JNB CSBESTOF,KA1NEXT
     
848. MOV @R0,#00H
     
849. DEC BUFF0
     
850. SJMP KA1NEXT2
     
851. KA1NEXT: CJNE R0,#7EH,KA1NEXT1
     
852. KA1NEXT1: JNC KA1NEXT2
     
853. MOV @R0,CSN
     
854. INC R0
     
855. MOV @R0,02H
     
856. INC R0
     
857. MOV @R0,03H
     
858. INC BUFF0
     
859. KA1NEXT2: LCALL CSNSDISN
     
860. SETB SECHSTOF
     
861. RET
     
862. CASE1: CJNE A,#01H,CASE2
     
863. INC RDYDSR
     
864. MOV A,RDYDSR
     
865. CJNE A,#04H,RDYDSL4
     
866. MOV RDYDSR,#00H
     
867. RDYDSL4: MOV DISNUM0,RDYDSR
     
868. MOV DISNUM1,#27H
     
869. RET
     
870. CASE2: CJNE A,#02H,CASE3
     
871. MOV A,COSPEEDN
     
872. JZ KA1NEXT5
     
873. DEC COSPEEDN
     
874. KA1NEXT5: MOV SPENR,COSPEEDN
     
875. LCALL SPENSDISN
     
876. RET
     
877. CASE3: CJNE A,#03H,CASE4
     
878. SETB SPEEDF
     
879. LCALL SPEEDCL
     
880. RET
     
881. CASE4: CJNE A,#04H,CASE5
     
882. SETB TONEF
     
883. LCALL TONECL
     
884. RET
     
885. CASE5: CJNE A,#05H,CASE6
     
886. CPL ROCF
     
887. JNB ROCF,KA1NEXT3
     
888. MOV DISNUM0,#24H
     
889. SJMP KA1NEXT4
     
890. KA1NEXT3: MOV DISNUM0,#25H
     
891. KA1NEXT4: MOV DISNUM1,#27H
     
892. RET
     
893. CASE6: CJNE A,#06H,KA1RET
     
894. MOV DISNUM0,#23H
     
895. MOV DISNUM1,#06H
     
896. KA1RET: RET
     
897. ;========= 乐曲表============
     
898. ;---------SONGS--------------
     
899. T_SONGS: 乐曲表表首
     
900. dw 01ffh,;song1:xiao la ba...
     
901. dw 0b05h,
     
902. dw 2504h,
     
903. dw 2604h,
     
904. dw 2506h,
     
905. dw 0002h,
     
906. dw 2504h,
     
907. dw 2604h,
     
908. dw 2506h,
     
909. dw 0002h,
     
910. dw 2504h,
     
911. dw 2604h,
     
912. dw 2504h,
     
913. dw 2304h,
     
914. dw 2204h,
     
915. dw 2104h,
     
916. dw 2206h,
     
917. 
     
918. DW 16FFH;SONG16:Liang Zhi Lao Hu
     
919. DW 0715H
     
920. DW 0FF21H ;REP21
     
921. DW 0FF01H ;REP01
     
922. DW 2102H
     
923. DW 2202H
     
924. DW 2302H
     
925. DW 2102H
     
926. DW 0FF02H ;REP02
     
927. DW 0FF03H ;REP03
     
928. DW 2302H
     
929. DW 2402H
     
930. DW 2504H
     
931. DW 2302H
     
932. DW 2402H
     
933. DW 2504H
     
934. DW 0FF11H ;REP11
     
935. DW 2501H
     
936. DW 2601H
     
937. DW 2501H
     
938. DW 2401H
     
939. DW 2302H
     
940. DW 2102H
     
941. DW 0FF12H ;REP12
     
942. DW 0FF13H ;REP13
     
943. DW 2202H
     
944. DW 1502H
     
945. DW 2104H
     
946. DW 2202H
     
947. DW 1502H
     
948. DW 2104H
     
949. DW 0FF22H ;REP22
     
950. DW 0FF23H ;REP23
     
951. 
     
952. DW 0000H ；乐曲表表尾
     
953. END
     
954. ;=========END================

复制代码